08/shaders/shader.frag

#version 420 core 

in vec2 texCoord;

in vec3 Cam_vertex; // Позиция камеры относительно вершины
in vec3 L_vertex; // Позиция источника света относительно вершины
in vec3 N; // Нормаль

layout(std140, binding = 1) uniform Material
{
    vec3 ka;
    vec3 kd;
    vec3 ks;
    float p;
};

layout(std140, binding = 2) uniform Light
{
    vec3 position;
    vec3 color;
} light_f;

uniform sampler2D tex_diffuse;
uniform sampler2D tex_ambient;
uniform sampler2D tex_specular;

layout (location = 0) out vec4 colors;
layout (location = 1) out vec4 normals;

void main() 
{ 
    // Диффузная составляющая
    float diffuse = max(dot(L_vertex, N), 0.0); // скалярное произведение с отсеканием значений < 0
    
    // Вектор половины пути
    vec3 H = normalize(L_vertex + Cam_vertex);
    // Зеркальная составляющая
    float specular = pow(max(dot(H, N), 0.0), p*4); // скалярное произведение с отсеканием значений < 0 в степени p

    colors = vec4(light_f.color*ka, 1)*texture(tex_ambient, texCoord) + vec4(light_f.color*kd*diffuse, 1)*texture(tex_diffuse, texCoord) + vec4(light_f.color*ks*specular, 1)*texture(tex_specular, texCoord);
    normals = vec4(N, 1.0);
}