16/shaders/gshader.frag

#version 420 core 

layout(std140, binding = 1) uniform Material
{
    vec3 ka;
    vec3 kd;
    vec3 ks;
    float p;
    bool normalmapped;
};

layout (location = 0) out vec3 gPosition;
layout (location = 1) out vec3 gNormal;
layout (location = 2) out vec4 gDiffuseP;
layout (location = 3) out vec4 gAmbientSpecular;

in vec3 vertex; // Позиция вершины в пространстве
in vec3 N; // Нормаль трансформированноая
in vec2 texCoord; // Текстурные координаты
in vec3 T; // Касательный вектор
in vec3 B; // Бикасательный вектор

uniform sampler2D tex_diffuse;
uniform sampler2D tex_ambient;
uniform sampler2D tex_specular;
uniform sampler2D tex_heights;
uniform sampler2D tex_normal;

void main()
{    
    // Сформируем TBN матрицу
    mat3 TBN = mat3(T, B, N);
    // Сохранение позиции фрагмента в G-буфере
    gPosition = vertex;
    // Сохранение нормали в G-буфере
    gNormal = N;
    // Если используется карта нормалей
    if (normalmapped)
    {
        // Получим значение из карты нормалей и приведем их к диапазону [-1;1]
        gNormal = texture(tex_normal, texCoord).rgb * 2 - 1.0f;  
        gNormal = normalize(TBN * gNormal); // Из касательного пространства в мировые координаты
    }

    // Сохранение диффузного цвета
    gDiffuseP.rgb = texture(tex_diffuse, texCoord).rgb * kd;
    // Сохранение глянцевости
    gDiffuseP.a = p;
    // Сохранение фоновой составляющей
    gAmbientSpecular.rgb = texture(tex_ambient, texCoord).rgb * ka;
    // Сохранение зеркальной составляющей
    gAmbientSpecular.a = texture(tex_specular, texCoord).r * ks.r;
}