Копия проекта с 19

shaders/bulb.frag

@@ -0,0 +1,43 @@
+#version 420 core 
+
+layout(std140, binding = 1) uniform Material
+{
+    vec3 base_color;
+    float roughness;
+    float metallic;
+    float specular;
+    vec3 emitted;
+    bool normalmapped;
+    bool parallaxmapped;
+    bool displacementmapped;
+};
+
+in vec3 pos_local;
+
+layout(std140, binding = 4) uniform gamma
+{
+    float inv_gamma;
+};
+
+layout (location = 1) out vec3 gNormal;
+layout (location = 4) out uvec3 gID;
+layout (location = 5) out vec3 gEmittedColor;
+
+uniform float angle;
+uniform vec3 direction;
+
+uniform uvec3 ID = uvec3(0);
+
+void main()
+{   
+    float cosA = dot(normalize(pos_local), normalize(direction));
+    if (degrees(acos(cosA)) <= angle)
+        gEmittedColor = pow(base_color, vec3(inv_gamma));
+    else
+        discard;
+
+    gNormal = vec3(0);
+    
+    // Сохранение идентификатора объекта
+    gID = ID;
+}

shaders/bulb.vert

@@ -0,0 +1,20 @@
+#version 420 core 
+
+layout(location = 0) in vec3 pos; 
+
+layout(std140, binding = 0) uniform Camera
+{
+    mat4 projection;
+    mat4 view;
+    vec3 position;
+} camera;
+
+uniform mat4 model;
+
+out vec3 pos_local;
+
+void main() 
+{ 
+    pos_local = pos;
+    gl_Position = camera.projection * camera.view * model * vec4(pos, 1.0);
+} 

shaders/empty.frag

@@ -0,0 +1,6 @@
+#version 330 core
+
+void main()
+{
+    
+}

shaders/gshader.frag

@@ -0,0 +1,126 @@
+#version 420 core 
+
+layout(std140, binding = 1) uniform Material
+{
+    vec3 base_color;
+    float roughness;
+    float metallic;
+    float specular;
+    vec3 emitted;
+    bool normalmapped;
+    bool parallaxmapped;
+    bool displacementmapped;
+};
+
+layout (location = 0) out vec3 gPosition;
+layout (location = 1) out vec3 gNormal;
+layout (location = 2) out vec3 gBaseColor;
+layout (location = 3) out vec3 gRMS;
+layout (location = 4) out uvec3 gID;
+layout (location = 5) out vec3 gEmittedColor;
+
+in vec3 vertex; // Позиция вершины в пространстве
+in vec3 N; // Нормаль трансформированноая
+in vec2 texCoord; // Текстурные координаты
+in vec3 T; // Касательный вектор
+in vec3 B; // Бикасательный вектор
+in vec3 view; // Вектор от поверхности к камере
+
+uniform sampler2D tex_albedo;
+uniform sampler2D tex_roughness;
+uniform sampler2D tex_metallic;
+uniform sampler2D tex_specular;
+uniform sampler2D tex_emitted;
+uniform sampler2D tex_heights;
+uniform sampler2D tex_normal;
+
+uniform float parallax_heightScale = 0.1;
+
+uniform uvec3 ID = uvec3(0);
+
+void main()
+{    
+    // Сформируем TBN матрицу
+    mat3 TBN = mat3(T, B, N);
+    // Перевод вектора в касательное пространство
+    vec3 viewTBN = normalize(transpose(TBN) * view);
+    // Измененные текстурные координаты
+    vec2 new_texCoord = texCoord;
+
+    // Сохранение позиции фрагмента в G-буфере
+    gPosition = vertex;
+
+    if (parallaxmapped)
+    {
+        // Число слоев
+        float layersCount = 32;  
+        // Вычислим размер каждого слоя
+        float layerDepth = 1.0 / layersCount;
+        // Глубина текущего слоя
+        float currentLayerDepth = 0.0;
+        // Величина сдвига между слоями
+        vec2 deltaTexCoords = (parallax_heightScale * viewTBN.xy / viewTBN.z) / layersCount;
+    
+        // Переменные для вычислений
+        vec2  currentTexCoords     = texCoord;
+        float currentDepthMapValue = 1.0 - texture(tex_heights, currentTexCoords).r;
+        
+        // Пока глубина текущего слоя меньше текущего значения глубины из текстуры 
+        while(currentLayerDepth < currentDepthMapValue)
+        {
+            // Сдвигаем координаты
+            currentTexCoords -= deltaTexCoords;
+            // Обновляем значение глубины из текстуры
+            currentDepthMapValue = 1.0 - texture(tex_heights, currentTexCoords).r;  
+            // Сдвигаем глубину на следующий слой
+            currentLayerDepth += layerDepth;  
+        }
+        
+        // Получим значение текстурных координат с предыдущего шага
+        vec2 prevTexCoords = currentTexCoords + deltaTexCoords;
+
+        // Значения глубины до и после пересечения
+        float afterDepth  = currentDepthMapValue - currentLayerDepth;
+        float beforeDepth = 1.0 - texture(tex_heights, prevTexCoords).r - currentLayerDepth + layerDepth;
+    
+        // Интерполяция текстурных координат
+        float weight = afterDepth / (afterDepth - beforeDepth);
+        new_texCoord = prevTexCoords * weight + currentTexCoords * (1.0 - weight);
+
+        // Проверка диапазона [0;1]
+        if(new_texCoord.x > 1.0 || new_texCoord.y > 1.0 || new_texCoord.x < 0.0 || new_texCoord.y < 0.0)
+            discard;
+    }
+
+    // Сохранение нормали в G-буфере
+    gNormal = N;
+    // Если используется карта нормалей
+    if (normalmapped)
+    {
+        // Получим значение из карты нормалей и приведем их к диапазону [-1;1]
+        gNormal = texture(tex_normal, new_texCoord).rgb * 2 - 1.0f;  
+        gNormal = normalize(TBN * gNormal); // Из касательного пространства в мировые координаты
+    }
+
+    // Сохранение базового цвета
+    gBaseColor.rgb = base_color.r<0?texture(tex_albedo, new_texCoord).rgb:base_color;
+    // Если используется двухканальная текстура
+    if (roughness < -1)
+    {
+        // Сохранение шероховатости и металличности
+        gRMS.rg = texture(tex_metallic, new_texCoord).bg;
+    }
+    else
+    {
+        // Сохранение шероховатости
+        gRMS.r = roughness<0?texture(tex_roughness, new_texCoord).r:roughness;
+        // Сохранение металличности
+        gRMS.g = metallic<0?texture(tex_metallic, new_texCoord).r:metallic;
+    }
+    // Сохранение интенсивности блика диэлектриков
+    gRMS.b = specular<0?texture(tex_specular, new_texCoord).r:specular;
+    // Сохранение идентификатора объекта
+    gID = ID;
+    // Сохранение излучаемого света
+    gEmittedColor.rgb = emitted.r<0?texture(tex_emitted, new_texCoord).rgb:emitted;
+}

shaders/gshader.vert

@@ -0,0 +1,61 @@
+#version 420 core 
+
+layout(location = 0) in vec3 pos; 
+layout(location = 1) in vec2 inTexCoord;
+layout(location = 2) in vec3 normals; 
+layout(location = 3) in vec3 tangent; 
+layout(location = 4) in vec3 bitangent; 
+
+layout(std140, binding = 0) uniform Camera
+{
+    mat4 projection;
+    mat4 view;
+    vec3 position;
+} camera;
+
+layout(std140, binding = 1) uniform Material
+{
+    vec3 base_color;
+    float roughness;
+    float metallic;
+    float specular;
+    vec3 emitted;
+    bool normalmapped;
+    bool parallaxmapped;
+    bool displacementmapped;
+};
+
+uniform sampler2D tex_heights;
+uniform float displacement_heightScale = 0.1;
+
+uniform mat4 model;
+
+out vec3 vertex; // Позиция вершины в пространстве
+out vec3 N; // Нормаль трансформированноая
+out vec2 texCoord; // Текстурные координаты
+out vec3 T; // Касательный вектор
+out vec3 B; // Бикасательный вектор
+out vec3 view; // Вектор от поверхности к камере
+
+void main() 
+{ 
+    vec4 P = model * vec4(pos, 1.0); // трансформация вершины
+    vertex = P.xyz;
+
+    N = normalize(mat3(model) * normals); // трансформация нормали
+
+    texCoord = inTexCoord; // Текстурные координаты
+
+    T = normalize(mat3(model) * tangent);
+    B = normalize(mat3(model) * bitangent);
+
+    view = camera.position - vertex;
+
+    if (displacementmapped)
+    {
+        float height = texture(tex_heights, texCoord).r * displacement_heightScale;
+        P.xyz += mat3(T, B, N) * vec3(0, 0, height);
+    }
+    
+    gl_Position = camera.projection * camera.view * P;
+} 

shaders/lighting.frag

@@ -0,0 +1,300 @@
+#version 420 core 
+
+in vec2 texCoord;
+
+layout(std140, binding = 0) uniform Camera
+{
+    mat4 projection;
+    mat4 view;
+    vec3 position;
+} camera;
+
+struct LightData
+{
+    vec3 position;
+    vec3 color;
+    vec3 attenuation;
+    vec4 direction_angle;
+    mat4 vp[6];
+};
+
+layout(std140, binding = 2) uniform Light
+{
+    LightData data[64];
+    int count;
+} light_f;
+
+layout(std140, binding = 3) uniform Sun
+{
+    vec3 direction;
+    vec3 color;
+    mat4 vp[4];
+} sun;
+
+uniform float camera_cascade_distances[4]; // Размер массива должен соответствовать количеству каскадов
+
+uniform sampler2D gPosition;
+uniform sampler2D gNormal;
+uniform sampler2D gBaseColor;
+uniform sampler2D gRMS;
+uniform sampler2D gEmittedColor;
+uniform sampler2DArray sunShadowDepth;
+uniform samplerCubeArray pointShadowDepth;
+uniform sampler2D ssao;
+uniform usampler2D gID;
+uniform samplerCube reflections;
+
+uniform uvec3 selectedID;
+
+layout(std140, binding = 4) uniform gamma
+{
+    float inv_gamma;
+};
+
+out vec4 color; 
+
+const float PI = 3.14159265359;
+
+float D(vec3 H, vec3 N, float a)
+{
+    float tmp = max(dot(N, H), 0);
+    tmp = tmp*tmp*(a*a-1)+1;
+    return a*a/(PI * tmp*tmp);
+}
+
+float G_Sclick_Beckmann(float NDotDir, float a)
+{
+    float tmp = (a+1)*(a+1) / 8;
+    return 1 / (NDotDir * (1 - tmp) + tmp);
+}
+
+float G_Smith(float LDotN, float CamDotN, float a)
+{
+    return G_Sclick_Beckmann(LDotN, a) * G_Sclick_Beckmann(CamDotN, a);
+}
+
+vec3 F(vec3 H, vec3 Cam_vertex, float metallic, float specular, vec3 base_color)
+{
+    vec3 F0 = mix(vec3(0.08 * specular), base_color, metallic);
+    return F0 + (1 - F0) * pow(1 - max(dot(H, Cam_vertex),0), 5);
+}
+
+float G_Sclick_Beckmann_HS(float NDotDir, float a)
+{
+    float tmp = (a+1)*(a+1) / 2;
+    return 1 / (NDotDir * (1 - tmp) + tmp);
+}
+
+float G_Smith_HS(float LDotN, float CamDotN, float a)
+{
+    return G_Sclick_Beckmann_HS(LDotN, a) * G_Sclick_Beckmann_HS(CamDotN, a);
+}
+
+vec3 F_roughness(vec3 H, vec3 Cam_vertex, float metallic, float roughness, float specular, vec3 base_color)
+{
+    vec3 F0 = mix(vec3(0.08 * specular), base_color, metallic);
+    return F0 + (max(vec3(1.0 - roughness), F0) - F0) * pow(1 - max(dot(H, Cam_vertex),0), 5);
+}
+
+void main() 
+{ 
+    // Получим данные из текстур буфера
+    vec3 fragPos = texture(gPosition, texCoord).rgb;
+    vec3 N = normalize(texture(gNormal, texCoord).rgb);
+    vec3 base_color = texture(gBaseColor, texCoord).rgb;
+    float roughness = texture(gRMS, texCoord).r;
+    float metallic = texture(gRMS, texCoord).g;
+    float specular = texture(gRMS, texCoord).b;
+    float ssao_value = texture(ssao, texCoord).r;
+    
+    // Переменные используемые в цикле:
+    vec3 L_vertex; // Расположение источника относительно фрагмента
+    float L_distance; // Расстояние от поверхности до источника
+    vec3 Cam_vertex = normalize(camera.position - fragPos); // Расположение камеры относительно фрагмента
+    vec3 ks; // Интенсивность зеркального отражения
+    vec3 fd, fs; // Диффузное и зеркальное отражения
+    vec3 H; // Вектор половины пути
+    float attenuation; // Угасание с учетом расстояния
+    float acosA; // Косинус между вектором от поверхности к источнику и обратным направлением источника
+    float intensity; // Интенсивность для прожектора
+    vec3 fragPosLightSpace; // Фрагмент в пространстве источника
+    float shadowValue; // Значение затененности
+    vec2 texelSize = 1.0 / textureSize(sunShadowDepth, 0).xy; // Размер текселя текстуры теней
+    int x, y, z; // Счетчик для PCF
+    float pcfDepth; // Глубина PCF
+    float cubemap_offset = 0.05f; // Отступ в текстурных координатах для PCF
+    float cubemap_depth; // Дистанция между фрагментом и источником в диапазоне [0;1]
+
+    vec4 fragPosCamSpace = camera.view * vec4(fragPos, 1); // Фрагмент в пространстве камеры
+    int cascade_index; // Индекс текущего каскада для вычисления теней
+    float CamDotN = dot(Cam_vertex,N); // Скалярное произведение вектора на камеру и нормали
+    float LDotN; // Скалярное произведение вектора на источник и нормали
+
+    // Определение индекса каскада в который попадает фрагмент (цикл на 1 меньше чем кол-во каскадов)
+    for (cascade_index = 0; cascade_index < 3; cascade_index++)
+        if (abs(fragPosCamSpace.z) < camera_cascade_distances[cascade_index])
+            break;
+
+    // Фоновая освещенность
+    color = vec4(texture(gEmittedColor, texCoord).rgb, 1);
+    
+    // Если у модели есть нормаль
+    if (length(N) > 0)
+    {
+        // Отражения на основании карт отражений
+        vec3 reflectedVec = reflect(-Cam_vertex, N);
+        vec3 reflectedColor = textureLod(reflections, reflectedVec, 6*roughness).rgb;
+
+        LDotN = dot(reflectedVec, N);
+
+        // Вектор половины пути
+        H = normalize(reflectedVec + Cam_vertex);
+
+        // Зеркальное отражение
+        ks = F_roughness(N, Cam_vertex, metallic, roughness, specular, base_color);
+        fs = ks * min(D(H, N, roughness*roughness) / 4, 1) * G_Smith_HS(LDotN, CamDotN, roughness*roughness);
+
+        // Результирующий цвет с учетом солнца
+        color.rgb += fs * reflectedColor * LDotN;
+
+        
+        // Расчет солнца, если его цвет не черный
+        if (length(sun.color) > 0)
+        {
+            // Расположение фрагмента в координатах теневой карты
+            fragPosLightSpace = (sun.vp[cascade_index] * vec4(fragPos, 1.0)).xyz;
+            // Переход от [-1;1] к [0;1]
+            fragPosLightSpace = (fragPosLightSpace + vec3(1.0)) / 2;
+            // Сдвиг для решения проблемы акне
+            fragPosLightSpace.z -= max(0.05 * (1.0 - dot(N, sun.direction)), 0.005);
+            // Проверка PCF
+            shadowValue = 0.0;
+            texelSize = 1.0 / textureSize(sunShadowDepth, 0).xy; // Размер текселя текстуры теней
+            for(x = -1; x <= 1; ++x)
+            {
+                for(y = -1; y <= 1; ++y)
+                {
+                    pcfDepth = texture(sunShadowDepth, vec3(fragPosLightSpace.xy + vec2(x, y) * texelSize, cascade_index)).r;
+                    shadowValue += fragPosLightSpace.z > pcfDepth  ? 1.0 : 0.0;        
+                }    
+            }
+            shadowValue /= 9.0;
+            // Рассчитываем освещенность, если значение тени меньше 1
+            if (shadowValue < 1.0)
+            {
+                // Данные об источнике относительно фрагмента
+                L_vertex = normalize(sun.direction);
+                LDotN = dot(L_vertex,N);
+                if (LDotN > 0)
+                {
+                    // Вектор половины пути
+                    H = normalize(L_vertex + Cam_vertex);
+
+                    // Зеркальное отражение
+                    ks = F(H, Cam_vertex, metallic, specular, base_color);
+                    fs = ks * min(D(H, N, roughness*roughness) / 4, 1) * G_Smith(LDotN, CamDotN, roughness*roughness);
+
+                    // Диффузное отражение
+                    fd = (1 - length(ks)/length(base_color)) * base_color;
+
+                    // Результирующий цвет с учетом солнца
+                    color.rgb += (fd + fs) * sun.color * LDotN * (1.0 - shadowValue);
+                }
+            }
+        } 
+
+        // Цикл по источникам света
+        int i;
+        for (i = 0; i < light_f.count; i++)
+        {
+            // Обнулим значение тени
+            shadowValue = 0;
+            // Позиция фрагмента относительно источника
+            fragPosLightSpace = fragPos - light_f.data[i].position;
+            // Дистанция между фрагментом и источником в диапазоне [0;1]
+            cubemap_depth = length(fragPosLightSpace) / light_f.data[i].attenuation.r;
+            // Сдвиг для решения проблемы акне
+            cubemap_depth -= max(0.05 * (1.0 - dot(N, sun.direction)), 0.005);
+            for(x = -1; x <= 1; ++x)
+            {
+                for(y = -1; y <= 1; ++y)
+                {
+                    for(z = -1; z <= 1; ++z)
+                    {
+                        // Значение из кубической текстуры с учетом источника (i)
+                        pcfDepth = texture(pointShadowDepth, vec4(fragPosLightSpace + vec3(x, y, z)*cubemap_offset, i)).r; 
+                        if(cubemap_depth > pcfDepth)
+                            shadowValue += 1.0;
+                    }
+                }
+            }
+            shadowValue /= (27);
+            if (shadowValue < 1.0)
+            {
+                // Данные об источнике относительно фрагмента
+                L_vertex = light_f.data[i].position - fragPos;
+                // Расстояние от поверхности до источника
+                L_distance = length(L_vertex);
+
+                // Проверка на дистанцию
+                if (L_distance < light_f.data[i].attenuation.r)
+                {
+                    // Нормирование вектора
+                    L_vertex = normalize(L_vertex);
+                    // арккосинус между вектором от поверхности к источнику и обратным направлением источника
+                    acosA = degrees(acos(dot(-L_vertex, normalize(light_f.data[i].direction_angle.rgb))));
+                    // Если угол меньше угла источника или угол источника минимален, то считаем освещенность
+                    if(acosA <= light_f.data[i].direction_angle.a) 
+                    {
+                        LDotN = dot(L_vertex,N);
+                        if (LDotN > 0)
+                        {
+                            // Вектор половины пути
+                            H = normalize(L_vertex + Cam_vertex);
+
+                            // Угасание с учетом расстояния
+                            attenuation = 1 / (1 + light_f.data[i].attenuation[1] * L_distance + light_f.data[i].attenuation[2] * L_distance * L_distance);
+
+                            // Зеркальное отражение
+                            ks = F(H, Cam_vertex, metallic, specular, base_color);
+                            fs = ks * min(D(H, N, roughness*roughness) / 4, 1) * G_Smith(LDotN, CamDotN, roughness*roughness);
+
+                            // Диффузное отражение
+                            fd = (1 - length(ks)/length(base_color)) * base_color;
+
+                            // Если источник - прожектор, то добавим смягчение
+                            if (light_f.data[i].direction_angle.a < 180)
+                            {
+                                intensity = clamp((light_f.data[i].direction_angle.a - acosA) / 5, 0.0, 1.0);  
+                                fd *= intensity;
+                                fs *= intensity;
+                            }
+
+                            color.rgb += (fd + fs) * light_f.data[i].color * attenuation * LDotN * (1.0 - shadowValue);
+                        }
+                    }
+                }
+            }
+        }
+    }
+
+    // Применение гамма-коррекции
+    color.rgb = pow(color.rgb * ssao_value, vec3(inv_gamma));
+
+    vec3 ID = texture(gID, texCoord).rgb;
+    // Обводка выбранного объекта
+    if (length(selectedID.rg) > 0 && selectedID.rg == ID.rg && ID.b == 0)
+    {
+        int border_width = 3;
+        vec2 size = 1.0f / textureSize(gID, 0);
+        for (int i = -border_width; i <= +border_width; i++)
+            for (int j = -border_width; j <= +border_width; j++)
+            {
+                if (i == 0 && j == 0)
+                    continue;
+
+                if (texture(gID, texCoord + vec2(i, j) * size).rg != selectedID.rg)
+                    color.rgb = vec3(1.0);
+            }
+    }
+} 

shaders/point_shadow.frag

@@ -0,0 +1,17 @@
+#version 330 core
+
+in vec4 FragPos;
+in vec3 lightPos;
+in float radius;
+
+void main()
+{
+    // Расстояние между источником и фрагментом
+    float lightDistance = length(FragPos.xyz - lightPos);
+    
+    // Приведение к диапазону [0;1]
+    lightDistance = lightDistance / radius;
+    
+    // Замена значения глубины
+    gl_FragDepth = lightDistance;
+}

shaders/point_shadow.geom

@@ -0,0 +1,38 @@
+#version 420 core
+layout (triangles, invocations = 6) in; // здесь invocations соответствует числу сторон кубической карты теней
+layout (triangle_strip, max_vertices=18) out; // здесь max_vertices = 3 вершины * 6 вызовов на стороны куба
+
+struct LightData
+{
+    vec3 position;
+    vec3 color;
+    vec3 attenuation;
+    vec4 direction_angle;
+    mat4 vp[6];
+};
+
+layout(std140, binding = 2) uniform Light
+{
+    LightData data[64];
+    int count;
+} light_g;
+
+uniform int light_i;
+
+out vec4 FragPos; 
+out vec3 lightPos;
+out float radius;
+
+void main()
+{
+    for(int i = 0; i < 3; ++i)
+    {
+        FragPos = gl_in[i].gl_Position;
+        lightPos = light_g.data[light_i].position;
+        radius = light_g.data[light_i].attenuation.r;
+        gl_Position = light_g.data[light_i].vp[gl_InvocationID] * gl_in[i].gl_Position;
+        gl_Layer = gl_InvocationID + light_i*6; 
+        EmitVertex();
+    }    
+    EndPrimitive();
+} 

shaders/quad.vert

@@ -0,0 +1,11 @@
+#version 420 core 
+
+layout(location = 0) in vec3 pos; 
+
+out vec2 texCoord;
+
+void main() 
+{ 
+    gl_Position = vec4(pos, 1.0);
+    texCoord = (pos.xy + vec2(1.0)) / 2; // Переход от [-1;1] к [0;1]
+}

shaders/skybox.frag

@@ -0,0 +1,17 @@
+#version 420 core
+out vec4 FragColor;
+
+in vec3 TexCoords;
+
+uniform samplerCube skybox;
+
+layout(std140, binding = 4) uniform gamma
+{
+    float inv_gamma;
+};
+
+void main()
+{    
+    FragColor.rgb = pow(texture(skybox, TexCoords).rgb, vec3(inv_gamma));
+    gl_FragDepth = 0.9999f;
+}

shaders/skybox.vert

@@ -0,0 +1,17 @@
+#version 420 core
+layout (location = 0) in vec3 pos;
+
+out vec3 TexCoords;
+
+layout(std140, binding = 0) uniform Camera
+{
+    mat4 projection;
+    mat4 view;
+    vec3 position;
+} camera;
+
+void main()
+{
+    TexCoords = pos;
+    gl_Position = camera.projection * mat4(mat3(camera.view)) * vec4(pos, 1.0);
+}  

shaders/ssao.frag

@@ -0,0 +1,62 @@
+#version 420 core
+
+in vec2 texCoord;
+
+out float occlusion;
+
+uniform sampler2D gPosition;
+uniform sampler2D gNormal;
+uniform sampler2D noise;
+
+layout(std140, binding = 0) uniform Camera
+{
+    mat4 projection;
+    mat4 view;
+    vec3 position;
+} camera;
+
+layout(std140, binding = 3) uniform SSAO
+{
+    float radius;
+    float bias;
+    int size;
+    vec2 scale;
+    vec3 samples[64];
+} ssao;
+
+void main()
+{
+    // Получим информацию из текстур для данного фрагмента по текстурным координатам
+    vec3 fragPos = (camera.view * vec4(texture(gPosition, texCoord).xyz, 1)).xyz;
+    vec3 normal = normalize(texture(gNormal, texCoord).rgb);
+    vec3 randomVec = normalize(texture(noise, texCoord * ssao.scale).xyz);
+    // Расчет TBN матрицы
+    vec3 tangent = normalize(randomVec - normal * dot(randomVec, normal));
+    vec3 bitangent = cross(normal, tangent);
+    mat3 TBN = mat3(tangent, bitangent, normal);
+    
+    float sampleDepth; // Значение глубины образца выборки
+    vec3 samplePos; // Выборка, ориентированная в пространстве вида камеры
+    vec4 sampleCoord; // Выборка, преобразованная к текстурным координатам
+    float rangeCheck; // Проверка диапазона
+    
+    // Проинициализируем значение счетчика и запустим цикл по выборкам
+    occlusion = 0;
+    for(int i = 0; i < ssao.size; i++)
+    {
+        samplePos = TBN * ssao.samples[i]; // в TBN-пространстве
+        samplePos = fragPos + samplePos * ssao.radius; // в пространстве вида камеры
+        
+        sampleCoord = camera.projection * vec4(samplePos, 1.0); 
+        sampleCoord.xyz /= sampleCoord.w; // Деление на значение перспективы
+        sampleCoord.xyz = sampleCoord.xyz * 0.5 + 0.5; // Трансформация в диапазон [0.0; 1.0]
+        
+        // Получаем значение глубины по образцу выборки
+        sampleDepth = (camera.view * vec4(texture(gPosition, sampleCoord.xy).rgb, 1)).z; 
+
+        rangeCheck = smoothstep(0.0, 1.0, ssao.radius / abs(fragPos.z - sampleDepth));
+        occlusion += (sampleDepth >= samplePos.z + ssao.bias ? 1.0 : 0.0) * rangeCheck;
+    }
+
+    occlusion = 1 - (occlusion / ssao.size);
+}

shaders/ssaoBlur.frag

@@ -0,0 +1,23 @@
+#version 330 core
+
+in vec2 texCoord;
+
+out float occlusion;
+
+uniform sampler2D ssao;
+
+void main() 
+{
+    vec2 texelSize = 1.0 / vec2(textureSize(ssao, 0));
+    vec2 offset;
+    occlusion = 0.0;
+    for (int x = -2; x < 2; x++) 
+    {
+        for (int y = -2; y < 2; y++) 
+        {
+            offset = vec2(x, y) * texelSize;
+            occlusion += texture(ssao, texCoord + offset).r;
+        }
+    }
+    occlusion = occlusion / (4.0 * 4.0);
+}  

shaders/sun_shadow.geom

@@ -0,0 +1,22 @@
+#version 420 core
+
+layout(triangles, invocations = 4) in; // здесь invocations должно соответствовать количеству каскадов
+layout(triangle_strip, max_vertices = 3) out;
+
+layout(std140, binding = 3) uniform Sun
+{
+    vec3 direction;
+    vec3 color;
+    mat4 vp[4];
+} sun;
+
+void main()
+{ 
+	for (int i = 0; i < 3; ++i)
+	{
+		gl_Position = sun.vp[gl_InvocationID] * gl_in[i].gl_Position;
+		gl_Layer = gl_InvocationID;
+		EmitVertex();
+	}
+	EndPrimitive();
+}  

shaders/sun_shadow.vert

@@ -0,0 +1,10 @@
+#version 420 core
+
+layout (location = 0) in vec3 pos;
+
+uniform mat4 model;
+
+void main()
+{
+    gl_Position = model * vec4(pos, 1.0);
+}

shaders/tools.frag

@@ -0,0 +1,39 @@
+#version 420 core 
+
+layout(std140, binding = 1) uniform Material
+{
+    vec3 base_color;
+    float roughness;
+    float metallic;
+    float specular;
+    vec3 emitted;
+    bool normalmapped;
+    bool parallaxmapped;
+    bool displacementmapped;
+};
+
+layout (location = 1) out vec3 gNormal;
+layout (location = 4) out uvec3 gID;
+layout (location = 5) out vec3 gEmittedColor;
+
+in vec3 vertex; // Позиция вершины в пространстве
+in vec3 N; // Нормаль трансформированная
+in vec2 texCoord; // Текстурные координаты
+in vec3 T; // Касательный вектор
+in vec3 B; // Бикасательный вектор
+in vec3 view; // Вектор от поверхности к камере
+
+uniform float parallax_heightScale = 0.1;
+
+uniform uvec3 ID = uvec3(0);
+
+void main()
+{    
+    gNormal = vec3(0);
+    // Сохранение базового цвета в качестве излучаемого
+    gEmittedColor = base_color;
+    // Сохранение идентификатора объекта
+    gID = ID;
+    
+    gl_FragDepth = 0.01 * gl_FragCoord.z;
+}