Копия 16

shaders/bulb.frag

@@ -0,0 +1,33 @@
+#version 420 core 
+
+layout(std140, binding = 1) uniform Material
+{
+    vec3 ka;
+    vec3 kd;
+    vec3 ks;
+    float p;
+    bool normalmapped;
+    bool parallaxmapped;
+    bool displacementmapped;
+};
+
+in vec3 pos_local;
+
+layout(std140, binding = 4) uniform gamma
+{
+    float inv_gamma;
+};
+
+out vec4 color;
+
+uniform float angle;
+uniform vec3 direction;
+
+void main()
+{   
+    float cosA = dot(normalize(pos_local), normalize(direction));
+    if (degrees(acos(cosA)) <= angle)
+        color = vec4(pow(ka, vec3(inv_gamma)), 1);
+    else
+        discard;
+}

shaders/bulb.vert

@@ -0,0 +1,20 @@
+#version 420 core 
+
+layout(location = 0) in vec3 pos; 
+
+layout(std140, binding = 0) uniform Camera
+{
+    mat4 projection;
+    mat4 view;
+    vec3 position;
+} camera;
+
+uniform mat4 model;
+
+out vec3 pos_local;
+
+void main() 
+{ 
+    pos_local = pos;
+    gl_Position = camera.projection * camera.view * model * vec4(pos, 1.0);
+} 

shaders/empty.frag

@@ -0,0 +1,6 @@
+#version 330 core
+
+void main()
+{
+    
+}

shaders/gshader.frag

@@ -0,0 +1,106 @@
+#version 420 core 
+
+layout(std140, binding = 1) uniform Material
+{
+    vec3 ka;
+    vec3 kd;
+    vec3 ks;
+    float p;
+    bool normalmapped;
+    bool parallaxmapped;
+    bool displacementmapped;
+};
+
+layout (location = 0) out vec3 gPosition;
+layout (location = 1) out vec3 gNormal;
+layout (location = 2) out vec4 gDiffuseP;
+layout (location = 3) out vec4 gAmbientSpecular;
+
+in vec3 vertex; // Позиция вершины в пространстве
+in vec3 N; // Нормаль трансформированноая
+in vec2 texCoord; // Текстурные координаты
+in vec3 T; // Касательный вектор
+in vec3 B; // Бикасательный вектор
+in vec3 view; // Вектор от поверхности к камере
+
+uniform sampler2D tex_diffuse;
+uniform sampler2D tex_ambient;
+uniform sampler2D tex_specular;
+uniform sampler2D tex_heights;
+uniform sampler2D tex_normal;
+
+uniform float parallax_heightScale = 0.1;
+
+void main()
+{    
+    // Сформируем TBN матрицу
+    mat3 TBN = mat3(T, B, N);
+    // Перевод вектора в касательное пространство
+    vec3 viewTBN = normalize(transpose(TBN) * view);
+    // Измененные текстурные координаты
+    vec2 new_texCoord = texCoord;
+
+    // Сохранение позиции фрагмента в G-буфере
+    gPosition = vertex;
+
+    if (parallaxmapped)
+    {
+        // Число слоев
+        float layersCount = 32;  
+        // Вычислим размер каждого слоя
+        float layerDepth = 1.0 / layersCount;
+        // Глубина текущего слоя
+        float currentLayerDepth = 0.0;
+        // Величина сдвига между слоями
+        vec2 deltaTexCoords = (parallax_heightScale * viewTBN.xy / viewTBN.z) / layersCount;
+    
+        // Переменные для вычислений
+        vec2  currentTexCoords     = texCoord;
+        float currentDepthMapValue = 1.0 - texture(tex_heights, currentTexCoords).r;
+        
+        // Пока глубина текущего слоя меньше текущего значения глубины из текстуры 
+        while(currentLayerDepth < currentDepthMapValue)
+        {
+            // Сдвигаем координаты
+            currentTexCoords -= deltaTexCoords;
+            // Обновляем значение глубины из текстуры
+            currentDepthMapValue = 1.0 - texture(tex_heights, currentTexCoords).r;  
+            // Сдвигаем глубину на следующий слой
+            currentLayerDepth += layerDepth;  
+        }
+        
+        // Получим значение текстурных координат с предыдущего шага
+        vec2 prevTexCoords = currentTexCoords + deltaTexCoords;
+
+        // Значения глубины до и после пересечения
+        float afterDepth  = currentDepthMapValue - currentLayerDepth;
+        float beforeDepth = 1.0 - texture(tex_heights, prevTexCoords).r - currentLayerDepth + layerDepth;
+    
+        // Интерполяция текстурных координат
+        float weight = afterDepth / (afterDepth - beforeDepth);
+        new_texCoord = prevTexCoords * weight + currentTexCoords * (1.0 - weight);
+
+        // Проверка диапазона [0;1]
+        if(new_texCoord.x > 1.0 || new_texCoord.y > 1.0 || new_texCoord.x < 0.0 || new_texCoord.y < 0.0)
+            discard;
+    }
+
+    // Сохранение нормали в G-буфере
+    gNormal = N;
+    // Если используется карта нормалей
+    if (normalmapped)
+    {
+        // Получим значение из карты нормалей и приведем их к диапазону [-1;1]
+        gNormal = texture(tex_normal, new_texCoord).rgb * 2 - 1.0f;  
+        gNormal = normalize(TBN * gNormal); // Из касательного пространства в мировые координаты
+    }
+
+    // Сохранение диффузного цвета
+    gDiffuseP.rgb = texture(tex_diffuse, new_texCoord).rgb * kd;
+    // Сохранение глянцевости
+    gDiffuseP.a = p;
+    // Сохранение фоновой составляющей
+    gAmbientSpecular.rgb = texture(tex_ambient, new_texCoord).rgb * ka;
+    // Сохранение зеркальной составляющей
+    gAmbientSpecular.a = texture(tex_specular, new_texCoord).r * ks.r;
+}

shaders/gshader.vert

@@ -0,0 +1,60 @@
+#version 420 core 
+
+layout(location = 0) in vec3 pos; 
+layout(location = 1) in vec2 inTexCoord;
+layout(location = 2) in vec3 normals; 
+layout(location = 3) in vec3 tangent; 
+layout(location = 4) in vec3 bitangent; 
+
+layout(std140, binding = 0) uniform Camera
+{
+    mat4 projection;
+    mat4 view;
+    vec3 position;
+} camera;
+
+layout(std140, binding = 1) uniform Material
+{
+    vec3 ka;
+    vec3 kd;
+    vec3 ks;
+    float p;
+    bool normalmapped;
+    bool parallaxmapped;
+    bool displacementmapped;
+};
+
+uniform sampler2D tex_heights;
+uniform float displacement_heightScale = 0.1;
+
+uniform mat4 model;
+
+out vec3 vertex; // Позиция вершины в пространстве
+out vec3 N; // Нормаль трансформированноая
+out vec2 texCoord; // Текстурные координаты
+out vec3 T; // Касательный вектор
+out vec3 B; // Бикасательный вектор
+out vec3 view; // Вектор от поверхности к камере
+
+void main() 
+{ 
+    vec4 P = model * vec4(pos, 1.0); // трансформация вершины
+    vertex = P.xyz;
+
+    N = normalize(mat3(model) * normals); // трансформация нормали
+
+    texCoord = inTexCoord; // Текстурные координаты
+
+    T = normalize(mat3(model) * tangent);
+    B = normalize(mat3(model) * bitangent);
+
+    view = camera.position - vertex;
+
+    if (displacementmapped)
+    {
+        float height = texture(tex_heights, texCoord).r * displacement_heightScale;
+        P.xyz += mat3(T, B, N) * vec3(0, 0, height);
+    }
+    
+    gl_Position = camera.projection * camera.view * P;
+} 

shaders/lighting.frag

@@ -0,0 +1,201 @@
+#version 420 core 
+
+in vec2 texCoord;
+
+layout(std140, binding = 0) uniform Camera
+{
+    mat4 projection;
+    mat4 view;
+    vec3 position;
+} camera;
+
+struct LightData
+{
+    vec3 position;
+    vec3 color;
+    vec3 attenuation;
+    vec4 direction_angle;
+    mat4 vp[6];
+};
+
+layout(std140, binding = 2) uniform Light
+{
+    LightData data[64];
+    int count;
+} light_f;
+
+layout(std140, binding = 3) uniform Sun
+{
+    vec3 direction;
+    vec3 color;
+    mat4 vp[4];
+} sun;
+
+uniform float camera_cascade_distances[4]; // Размер массива должен соответствовать количеству каскадов
+
+uniform sampler2D gPosition;
+uniform sampler2D gNormal;
+uniform sampler2D gDiffuseP;
+uniform sampler2D gAmbientSpecular;
+uniform sampler2DArray sunShadowDepth;
+uniform samplerCubeArray pointShadowDepth;
+uniform sampler2D ssao;
+
+layout(std140, binding = 4) uniform gamma
+{
+    float inv_gamma;
+};
+
+out vec4 color; 
+
+void main() 
+{ 
+    // Получим данные из текстур буфера
+    vec3 fragPos = texture(gPosition, texCoord).rgb;
+    vec3 N = texture(gNormal, texCoord).rgb;
+    vec3 kd = texture(gDiffuseP, texCoord).rgb;
+    vec3 ka = texture(gAmbientSpecular, texCoord).rgb;
+    float ks = texture(gAmbientSpecular, texCoord).a;
+    float p = texture(gDiffuseP, texCoord).a;
+    float ssao_value = texture(ssao, texCoord).r;
+    
+    // Переменные используемые в цикле:
+    vec3 L_vertex; // Данные об источнике относительно фрагмента
+    vec3 Cam_vertex = normalize(camera.position - fragPos); // Данные о камере относительно фрагмента
+    float diffuse; // Диффузная составляющая
+    vec3 H; // Вектор половины пути
+    float specular; // Зеркальная составляющая
+    float L_distance; // Расстояние от поверхности до источника
+    float attenuation; // Коэф. угасания
+    float acosA; // Косинус между вектором от поверхности к источнику и обратным направлением источника
+    float intensity; // Интенсивность для прожектора
+    vec3 fragPosLightSpace; // Фрагмент в пространстве источника
+    float shadowValue; // Значение затененности
+    vec2 texelSize = 1.0 / textureSize(sunShadowDepth, 0).xy; // Размер текселя текстуры теней
+    int x, y, z; // Счетчик для PCF
+    float pcfDepth; // Глубина PCF
+    float cubemap_offset = 0.05f; // Отступ в текстурных координатах для PCF
+    float cubemap_depth; // Дистанция между фрагментом и источником в диапазоне [0;1]
+
+    vec4 fragPosCamSpace = camera.view * vec4(fragPos, 1); // Фрагмент в пространстве камеры
+    int cascade_index; // Индекс текущего каскада для вычисления теней
+
+    // Определение индекса каскада в который попадает фрагмент (цикл на 1 меньше чем кол-во каскадов)
+    for (cascade_index = 0; cascade_index < 3; cascade_index++)
+        if (abs(fragPosCamSpace.z) < camera_cascade_distances[cascade_index])
+            break;
+
+    // Фоновая освещенность
+    color = vec4(ka, 1) * ssao_value;
+   
+    // Расчет солнца, если его цвет не черный
+    if (length(sun.color) > 0)
+    {
+        // Расположение фрагмента в координатах теневой карты
+        fragPosLightSpace = (sun.vp[cascade_index] * vec4(fragPos, 1.0)).xyz;
+        // Переход от [-1;1] к [0;1]
+        fragPosLightSpace = (fragPosLightSpace + vec3(1.0)) / 2;
+        // Сдвиг для решения проблемы акне
+        fragPosLightSpace.z -= max(0.05 * (1.0 - dot(N, sun.direction)), 0.005);
+        // Проверка PCF
+        shadowValue = 0.0;
+        for(x = -1; x <= 1; ++x)
+        {
+            for(y = -1; y <= 1; ++y)
+            {
+                pcfDepth = texture(sunShadowDepth, vec3(fragPosLightSpace.xy + vec2(x, y) * texelSize, cascade_index)).r;
+                shadowValue += fragPosLightSpace.z > pcfDepth  ? 1.0 : 0.0;        
+            }
+        }
+        shadowValue /= 9;
+        // Рассчитываем освещенность, если значение тени меньше 1
+        if (shadowValue < 1.0)
+        {
+            // Данные об источнике относительно фрагмента
+            L_vertex = normalize(sun.direction);
+            // Диффузная составляющая
+            diffuse = max(dot(L_vertex, N), 0.0); // скалярное произведение с отсеканием значений < 0
+            
+            // Вектор половины пути
+            H = normalize(L_vertex + Cam_vertex);
+            // Зеркальная составляющая
+            specular = pow(max(dot(H, N), 0.0), p*4); // скалярное произведение с отсеканием значений < 0 в степени p
+            // Результирующий цвет с учетом солнца
+            color += (  vec4(sun.color*kd*diffuse,  1)  
+                      + vec4(sun.color*ks*specular, 1) ) * (1.0 - shadowValue);
+        }
+    }
+
+    // Цикл по источникам света
+    int i;
+    for (i = 0; i < light_f.count; i++)
+    {
+        // Обнулим значение тени
+        shadowValue = 0;
+        // Позиция фрагмента относительно источника
+        fragPosLightSpace = fragPos - light_f.data[i].position;
+        // Дистанция между фрагментом и источником в диапазоне [0;1]
+        cubemap_depth = length(fragPosLightSpace) / light_f.data[i].attenuation.r;
+        // Сдвиг для решения проблемы акне
+        cubemap_depth -= max(0.05 * (1.0 - dot(N, light_f.data[i].direction_angle.xyz)), 0.005);
+        for(x = -1; x <= 1; ++x)
+        {
+            for(y = -1; y <= 1; ++y)
+            {
+                for(z = -1; z <= 1; ++z)
+                {
+                    // Значение из кубической текстуры с учетом источника (i)
+                    pcfDepth = texture(pointShadowDepth, vec4(fragPosLightSpace + vec3(x, y, z)*cubemap_offset, i)).r; 
+                    if(cubemap_depth > pcfDepth)
+                        shadowValue += 1.0;
+                }
+            }
+        }
+        shadowValue /= (27);
+        if (shadowValue < 1.0)
+        {
+            // Данные об источнике относительно фрагмента
+            L_vertex = light_f.data[i].position - fragPos;
+
+            // Расстояние от поверхности до источника
+            L_distance = length(L_vertex);
+            
+            // Проверка на дистанцию
+            if (L_distance < light_f.data[i].attenuation.r)
+            {
+                // Нормирование вектора
+                L_vertex = normalize(L_vertex);
+                // арккосинус между вектором от поверхности к источнику и обратным направлением источника
+                acosA = degrees(acos(dot(-L_vertex, normalize(light_f.data[i].direction_angle.xyz))));
+                // Если угол меньше угла источника или угол источника минимален, то считаем освещенность
+                if(acosA <= light_f.data[i].direction_angle.a) 
+                {
+                    // Диффузная составляющая
+                    diffuse = max(dot(L_vertex, N), 0.0); // скалярное произведение с отсеканием значений < 0
+                    
+                    // Вектор половины пути
+                    H = normalize(L_vertex + Cam_vertex);
+                    // Зеркальная составляющая
+                    specular = pow(max(dot(H, N), 0.0), p*4); // скалярное произведение с отсеканием значений < 0 в степени p
+
+                    // Угасание с учетом расстояния
+                    attenuation = 1 / (1 + light_f.data[i].attenuation[1] * L_distance + light_f.data[i].attenuation[2] * L_distance * L_distance);
+
+                    // Если источник - прожектор, то добавим смягчение
+                    if (light_f.data[i].direction_angle.a < 180)
+                    {
+                        intensity = clamp((light_f.data[i].direction_angle.a - acosA) / 5, 0.0, 1.0);  
+                        diffuse  *= intensity;
+                        specular *= intensity;
+                    }
+
+                    color += ( vec4(light_f.data[i].color*kd*diffuse  * attenuation, 1) 
+                              + vec4(light_f.data[i].color*ks*specular * attenuation, 1) )  * (1.0 - shadowValue);
+                }
+            }
+        }
+    }
+
+    // Применение гамма-коррекции
+    color.rgb = pow(color.rgb, vec3(inv_gamma));
+} 

shaders/point_shadow.frag

@@ -0,0 +1,17 @@
+#version 330 core
+
+in vec4 FragPos;
+in vec3 lightPos;
+in float radius;
+
+void main()
+{
+    // Расстояние между источником и фрагментом
+    float lightDistance = length(FragPos.xyz - lightPos);
+    
+    // Приведение к диапазону [0;1]
+    lightDistance = lightDistance / radius;
+    
+    // Замена значения глубины
+    gl_FragDepth = lightDistance;
+}

shaders/point_shadow.geom

@@ -0,0 +1,38 @@
+#version 420 core
+layout (triangles, invocations = 6) in; // здесь invocations соответствует числу сторон кубической карты теней
+layout (triangle_strip, max_vertices=18) out; // здесь max_vertices = 3 вершины * 6 вызовов на стороны куба
+
+struct LightData
+{
+    vec3 position;
+    vec3 color;
+    vec3 attenuation;
+    vec4 direction_angle;
+    mat4 vp[6];
+};
+
+layout(std140, binding = 2) uniform Light
+{
+    LightData data[64];
+    int count;
+} light_g;
+
+uniform int light_i;
+
+out vec4 FragPos; 
+out vec3 lightPos;
+out float radius;
+
+void main()
+{
+    for(int i = 0; i < 3; ++i)
+    {
+        FragPos = gl_in[i].gl_Position;
+        lightPos = light_g.data[light_i].position;
+        radius = light_g.data[light_i].attenuation.r;
+        gl_Position = light_g.data[light_i].vp[gl_InvocationID] * gl_in[i].gl_Position;
+        gl_Layer = gl_InvocationID + light_i*6; 
+        EmitVertex();
+    }    
+    EndPrimitive();
+} 

shaders/quad.vert

@@ -0,0 +1,11 @@
+#version 420 core 
+
+layout(location = 0) in vec3 pos; 
+
+out vec2 texCoord;
+
+void main() 
+{ 
+    gl_Position = vec4(pos, 1.0);
+    texCoord = (pos.xy + vec2(1.0)) / 2; // Переход от [-1;1] к [0;1]
+}

shaders/skybox.frag

@@ -0,0 +1,17 @@
+#version 420 core
+out vec4 FragColor;
+
+in vec3 TexCoords;
+
+uniform samplerCube skybox;
+
+layout(std140, binding = 4) uniform gamma
+{
+    float inv_gamma;
+};
+
+void main()
+{    
+    FragColor.rgb = pow(texture(skybox, TexCoords).rgb, vec3(inv_gamma));
+    gl_FragDepth = 0.9999f;
+}

shaders/skybox.vert

@@ -0,0 +1,17 @@
+#version 420 core
+layout (location = 0) in vec3 pos;
+
+out vec3 TexCoords;
+
+layout(std140, binding = 0) uniform Camera
+{
+    mat4 projection;
+    mat4 view;
+    vec3 position;
+} camera;
+
+void main()
+{
+    TexCoords = pos;
+    gl_Position = camera.projection * mat4(mat3(camera.view)) * vec4(pos, 1.0);
+}  

shaders/ssao.frag

@@ -0,0 +1,62 @@
+#version 420 core
+
+in vec2 texCoord;
+
+out float occlusion;
+
+uniform sampler2D gPosition;
+uniform sampler2D gNormal;
+uniform sampler2D noise;
+
+layout(std140, binding = 0) uniform Camera
+{
+    mat4 projection;
+    mat4 view;
+    vec3 position;
+} camera;
+
+layout(std140, binding = 3) uniform SSAO
+{
+    float radius;
+    float bias;
+    int size;
+    vec2 scale;
+    vec3 samples[64];
+} ssao;
+
+void main()
+{
+    // Получим информацию из текстур для данного фрагмента по текстурным координатам
+    vec3 fragPos = (camera.view * vec4(texture(gPosition, texCoord).xyz, 1)).xyz;
+    vec3 normal = normalize(texture(gNormal, texCoord).rgb);
+    vec3 randomVec = normalize(texture(noise, texCoord * ssao.scale).xyz);
+    // Расчет TBN матрицы
+    vec3 tangent = normalize(randomVec - normal * dot(randomVec, normal));
+    vec3 bitangent = cross(normal, tangent);
+    mat3 TBN = mat3(tangent, bitangent, normal);
+    
+    float sampleDepth; // Значение глубины образца выборки
+    vec3 samplePos; // Выборка, ориентированная в пространстве вида камеры
+    vec4 sampleCoord; // Выборка, преобразованная к текстурным координатам
+    float rangeCheck; // Проверка диапазона
+    
+    // Проинициализируем значение счетчика и запустим цикл по выборкам
+    occlusion = 0;
+    for(int i = 0; i < ssao.size; i++)
+    {
+        samplePos = TBN * ssao.samples[i]; // в TBN-пространстве
+        samplePos = fragPos + samplePos * ssao.radius; // в пространстве вида камеры
+        
+        sampleCoord = camera.projection * vec4(samplePos, 1.0); 
+        sampleCoord.xyz /= sampleCoord.w; // Деление на значение перспективы
+        sampleCoord.xyz = sampleCoord.xyz * 0.5 + 0.5; // Трансформация в диапазон [0.0; 1.0]
+        
+        // Получаем значение глубины по образцу выборки
+        sampleDepth = (camera.view * vec4(texture(gPosition, sampleCoord.xy).rgb, 1)).z; 
+
+        rangeCheck = smoothstep(0.0, 1.0, ssao.radius / abs(fragPos.z - sampleDepth));
+        occlusion += (sampleDepth >= samplePos.z + ssao.bias ? 1.0 : 0.0) * rangeCheck;
+    }
+
+    occlusion = 1 - (occlusion / ssao.size);
+}

shaders/ssaoBlur.frag

@@ -0,0 +1,23 @@
+#version 330 core
+
+in vec2 texCoord;
+
+out float occlusion;
+
+uniform sampler2D ssao;
+
+void main() 
+{
+    vec2 texelSize = 1.0 / vec2(textureSize(ssao, 0));
+    vec2 offset;
+    occlusion = 0.0;
+    for (int x = -2; x < 2; x++) 
+    {
+        for (int y = -2; y < 2; y++) 
+        {
+            offset = vec2(x, y) * texelSize;
+            occlusion += texture(ssao, texCoord + offset).r;
+        }
+    }
+    occlusion = occlusion / (4.0 * 4.0);
+}  

shaders/sun_shadow.geom

@@ -0,0 +1,22 @@
+#version 420 core
+
+layout(triangles, invocations = 4) in; // здесь invocations должно соответствовать количеству каскадов
+layout(triangle_strip, max_vertices = 3) out;
+
+layout(std140, binding = 3) uniform Sun
+{
+    vec3 direction;
+    vec3 color;
+    mat4 vp[4];
+} sun;
+
+void main()
+{ 
+	for (int i = 0; i < 3; ++i)
+	{
+		gl_Position = sun.vp[gl_InvocationID] * gl_in[i].gl_Position;
+		gl_Layer = gl_InvocationID;
+		EmitVertex();
+	}
+	EndPrimitive();
+}  

shaders/sun_shadow.vert

@@ -0,0 +1,10 @@
+#version 420 core
+
+layout (location = 0) in vec3 pos;
+
+uniform mat4 model;
+
+void main()
+{
+    gl_Position = model * vec4(pos, 1.0);
+}