#version 420 core 

in vec2 texCoord;

layout(std140, binding = 0) uniform Camera
{
    mat4 projection;
    mat4 view;
    vec3 position;
} camera;

layout(std140, binding = 2) uniform Light
{
    vec3 position;
    vec3 color;
} light_f;

uniform sampler2D gPosition;
uniform sampler2D gNormal;
uniform sampler2D gDiffuseP;
uniform sampler2D gAmbientSpecular;

out vec4 color; 

void main() 
{ 
    // Получим данные из текстур буфера
    vec3 fragPos = texture(gPosition, texCoord).rgb;
    vec3 N = texture(gNormal, texCoord).rgb;
    vec3 kd = texture(gDiffuseP, texCoord).rgb;
    vec3 ka = texture(gAmbientSpecular, texCoord).rgb;
    float ks = texture(gAmbientSpecular, texCoord).a;
    float p = texture(gDiffuseP, texCoord).a;
    
    // Данные о камере относительно фрагмента
    vec3 Cam_vertex = normalize(camera.position - fragPos);
    // Данные об источнике отностиельно фрагмента
    vec3 L_vertex = normalize(light_f.position - fragPos);

    // Диффузная составляющая
    float diffuse = max(dot(L_vertex, N), 0.0); // скалярное произведение с отсеканием значений < 0
    
    // Вектор половины пути
	vec3 H = normalize(L_vertex + Cam_vertex);
    // Зеркальная составляющая
    float specular = pow(max(dot(H, N), 0.0), p*4); // скалярное произведение с отсеканием значений < 0 в степени p

    color = vec4(ka, 1)
          + vec4(light_f.color*kd*diffuse, 1) 
          + vec4(light_f.color*ks*specular, 1);
}