#version 420 core 

in vec2 texCoord;

layout(std140, binding = 0) uniform Camera
{
    mat4 projection;
    mat4 view;
    vec3 position;
} camera;

struct LightData
{
    vec3 position;
    vec3 color;
};

layout(std140, binding = 2) uniform Light
{
    LightData data[300];
    int count;
} light_f;

uniform sampler2D gPosition;
uniform sampler2D gNormal;
uniform sampler2D gDiffuseP;
uniform sampler2D gAmbientSpecular;

out vec4 color; 

void main() 
{ 
    // Получим данные из текстур буфера
    vec3 fragPos = texture(gPosition, texCoord).rgb;
    vec3 N = texture(gNormal, texCoord).rgb;
    vec3 kd = texture(gDiffuseP, texCoord).rgb;
    vec3 ka = texture(gAmbientSpecular, texCoord).rgb;
    float ks = texture(gAmbientSpecular, texCoord).a;
    float p = texture(gDiffuseP, texCoord).a;
    
    // Переменные используемые в цикле:
    vec3 L_vertex; // Данные об источнике относительно фрагмента
    vec3 Cam_vertex = normalize(camera.position - fragPos); // Данные о камере относительно фрагмента
    float diffuse; // Диффузная составляющая
    vec3 H; // Вектор половины пути
    float specular; // Зеркальная составляющая
    
    // Фоновая освещенность
    color = vec4(ka, 1);

    // Цикл по источникам света
    int i;
    for (i = 0; i < light_f.count; i++)
    {
        // Данные об источнике относительно фрагмента
        L_vertex = light_f.data[i].position - fragPos;

        // Нормирование вектора
        L_vertex = normalize(L_vertex);

        // Диффузная составляющая
        diffuse = max(dot(L_vertex, N), 0.0); // скалярное произведение с отсеканием значений < 0
        
        // Вектор половины пути
        H = normalize(L_vertex + Cam_vertex);
        // Зеркальная составляющая
        specular = pow(max(dot(H, N), 0.0), p*4); // скалярное произведение с отсеканием значений < 0 в степени p

        color += vec4(light_f.data[i].color*kd*diffuse, 1) 
              +  vec4(light_f.data[i].color*ks*specular, 1);
    }
}